From fb03c300258b5d1dc419d7d08ecb3afa12a2fa5b Mon Sep 17 00:00:00 2001
From: Dave Arter <davea@mysociety.org>
Date: Mon, 24 Jul 2017 09:59:06 +0100
Subject: Add site-wide extra fields for reports, and admin UI to manage

 - Also provides an editor for the extra Open311 fields on contacts.
 - Adds .btn--small class for small buttons

Fixes #1743.
---
 .../App/Controller/Admin/ReportExtraFields.pm      | 61 ++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 perllib/FixMyStreet/App/Controller/Admin/ReportExtraFields.pm

(limited to 'perllib/FixMyStreet/App/Controller/Admin/ReportExtraFields.pm')

diff --git a/perllib/FixMyStreet/App/Controller/Admin/ReportExtraFields.pm b/perllib/FixMyStreet/App/Controller/Admin/ReportExtraFields.pm
new file mode 100644
index 000000000..d5ec64698
--- /dev/null
+++ b/perllib/FixMyStreet/App/Controller/Admin/ReportExtraFields.pm
@@ -0,0 +1,61 @@
+package FixMyStreet::App::Controller::Admin::ReportExtraFields;
+use Moose;
+use namespace::autoclean;
+use List::MoreUtils qw(uniq);
+
+BEGIN { extends 'Catalyst::Controller'; }
+
+
+sub begin : Private {
+    my ( $self, $c ) = @_;
+
+    $c->forward('/admin/begin');
+}
+
+sub index : Path : Args(0) {
+    my ( $self, $c ) = @_;
+
+    my @extras = $c->model('DB::ReportExtraFields')->search(
+        undef,
+        {
+            order_by => 'name'
+        }
+    );
+
+    $c->stash->{extra_fields} = \@extras;
+}
+
+sub edit : Path : Args(1) {
+    my ( $self, $c, $extra_id ) = @_;
+
+    my $extra;
+    if ( $extra_id eq 'new' ) {
+        $extra = $c->model('DB::ReportExtraFields')->new({});
+    } else {
+        $extra = $c->model('DB::ReportExtraFields')->find( $extra_id )
+            or $c->detach( '/page_error_404_not_found' );
+    }
+
+    if ($c->req->method eq 'POST') {
+        $c->forward('/auth/check_csrf_token');
+
+        foreach (qw/name cobrand language/) {
+            $extra->$_($c->get_param($_));
+        }
+        $c->forward('/admin/update_extra_fields', [ $extra ]);
+
+        $extra->update_or_insert;
+    }
+
+    $c->forward('/auth/get_csrf_token');
+    $c->forward('/admin/fetch_languages');
+
+    my @cobrands = uniq sort map { $_->{moniker} } FixMyStreet::Cobrand->available_cobrand_classes;
+    $c->stash->{cobrands} = \@cobrands;
+
+    $c->stash->{extra} = $extra;
+}
+
+__PACKAGE__->meta->make_immutable;
+
+1;
-- 
cgit v1.2.3