Merge branch 'migrate_to_catalyst' into reportemptyhomes

1 files changed, 175 insertions, 0 deletions

diff --git a/perllib/FixMyStreet/DB/ResultSet/Problem.pm b/perllib/FixMyStreet/DB/ResultSet/Problem.pm
new file mode 100644
index 000000000..589745dff
--- /dev/null
+++ b/perllib/FixMyStreet/DB/ResultSet/Problem.pm
@@ -0,0 +1,175 @@
+package FixMyStreet::DB::ResultSet::Problem;
+use base 'DBIx::Class::ResultSet';
+
+use strict;
+use warnings;
+
+my $site_restriction;
+my $site_key;
+
+sub set_restriction {
+    my ( $rs, $sql, $key, $restriction ) = @_;
+    $site_key = $key;
+    $site_restriction = $restriction;
+}
+
+# Front page statistics
+
+sub recent_fixed {
+    my $rs = shift;
+    my $key = "recent_fixed:$site_key";
+    my $result = Memcached::get($key);
+    unless ($result) {
+        $result = $rs->search( {
+            state => 'fixed',
+            lastupdate => { '>', \"current_timestamp-'1 month'::interval" },
+        } )->count;
+        Memcached::set($key, $result, 3600);
+    }
+    return $result;
+}
+
+sub number_comments {
+    my $rs = shift;
+    my $key = "number_comments:$site_key";
+    my $result = Memcached::get($key);
+    unless ($result) {
+        $result = $rs->search(
+            { 'comments.state' => 'confirmed' },
+            { join => 'comments' }
+        )->count;
+        Memcached::set($key, $result, 3600);
+    }
+    return $result;
+}
+
+sub recent_new {
+    my ( $rs, $interval ) = @_;
+    (my $key = $interval) =~ s/\s+//g;
+    $key = "recent_new:$site_key:$key";
+    my $result = Memcached::get($key);
+    unless ($result) {
+        $result = $rs->search( {
+            state => [ 'confirmed', 'fixed' ],
+            confirmed => { '>', \"current_timestamp-'$interval'::interval" },
+        } )->count;
+        Memcached::set($key, $result, 3600);
+    }
+    return $result;
+}
+
+# Front page recent lists
+
+sub recent {
+    my ( $rs ) = @_;
+    my $key = "recent:$site_key";
+    my $result = Memcached::get($key);
+    unless ($result) {
+        $result = [ $rs->search( {
+            state => [ 'confirmed', 'fixed' ]
+        }, {
+            columns => [ 'id', 'title' ],
+            order_by => { -desc => 'confirmed' },
+            rows => 5,
+        } )->all ];
+        Memcached::set($key, $result, 3600);
+    }
+    return $result;
+}
+
+sub recent_photos {
+    my ( $rs, $num, $lat, $lon, $dist ) = @_;
+    my $probs;
+    my $query = {
+        state => [ 'confirmed', 'fixed' ],
+        photo => { '!=', undef },
+    };
+    my $attrs = {
+        columns => [ 'id', 'title' ],
+        order_by => { -desc => 'confirmed' },
+        rows => $num,
+    };
+    if (defined $lat) {
+        my $dist2 = $dist; # Create a copy of the variable to stop it being stringified into a locale in the next line!
+        my $key = "recent_photos:$site_key:$num:$lat:$lon:$dist2";
+        $probs = Memcached::get($key);
+        unless ($probs) {
+            $attrs->{bind} = [ $lat, $lon, $dist ];
+            $attrs->{join} = 'nearby';
+            $probs = [ mySociety::Locale::in_gb_locale {
+                $rs->search( $query, $attrs )->all;
+            } ];
+            Memcached::set($key, $probs, 3600);
+        }
+    } else {
+        my $key = "recent_photos:$site_key:$num";
+        $probs = Memcached::get($key);
+        unless ($probs) {
+            $probs = [ $rs->search( $query, $attrs )->all ];
+            Memcached::set($key, $probs, 3600);
+        }
+    }
+    return $probs;
+}
+
+# Problems around a location
+
+sub around_map {
+    my ( $rs, $min_lat, $max_lat, $min_lon, $max_lon, $interval, $limit ) = @_;
+    my $attr = {
+        order_by => { -desc => 'created' },
+        columns => [
+            'id', 'title' ,'latitude', 'longitude', 'state', 'confirmed'
+        ],
+    };
+    $attr->{rows} = $limit if $limit;
+
+    my $q = {
+            state => [ 'confirmed', 'fixed' ],
+            latitude => { '>=', $min_lat, '<', $max_lat },
+            longitude => { '>=', $min_lon, '<', $max_lon },
+    };
+    $q->{'current_timestamp - lastupdate'} = { '<', \"'$interval'::interval" };
+
+    my @problems = mySociety::Locale::in_gb_locale { $rs->search( $q, $attr )->all };
+    return \@problems;
+}
+
+# Admin functions
+
+sub timeline {
+    my ( $rs ) = @_;
+
+    my $prefetch = 
+        FixMyStreet::App->model('DB')->schema->storage->sql_maker->quote_char ?
+        [ qw/user/ ] :
+        [];
+
+    return $rs->search(
+        {
+            -or => {
+                created  => { '>=', \"ms_current_timestamp()-'7 days'::interval" },
+                confirmed => { '>=', \"ms_current_timestamp()-'7 days'::interval" },
+                whensent  => { '>=', \"ms_current_timestamp()-'7 days'::interval" },
+            }
+        },
+        {
+            prefetch => $prefetch,
+        }
+    );
+}
+
+sub summary_count {
+    my ( $rs, $restriction ) = @_;
+
+    return $rs->search(
+        $restriction,
+        {
+            group_by => ['state'],
+            select   => [ 'state', { count => 'id' } ],
+            as       => [qw/state state_count/]
+        }
+    );
+}
+
+1;