blob: 90aa41cd8287739c7d109832bf9390fc5c7292c5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
#!ipxe
:start
chain --autofree boot.cfg ||
iseq ${cls} serial && goto ignore_cls ||
set cls:hex 1b:5b:4a # ANSI clear screen sequence - "^[[J"
set cls ${cls:string}
:ignore_cls
isset ${arch} && goto skip_arch_detect ||
cpuid --ext 29 && set arch x86_64 || set arch i386
iseq ${buildarch} arm64 && set arch arm64 ||
:skip_arch_detect
isset ${menu} && goto ${menu} ||
isset ${ip} || dhcp || echo DHCP failed
:main_menu
console --x 640 --y 480
console --picture ${bg_image} --left 240 --right 10 --top 15 --bottom 32
clear menu
set space:hex 20:20
set space ${space:string}
iseq ${arch} x86_64 && set arch_a amd64 || set arch_a ${arch}
menu ${site_name}
item --gap Default:
item local ${space} Boot from local disk
item --gap Distributions:
iseq ${menu_linux} 1 && item linux ${space} Linux Installs ||
#iseq ${menu_bsd} 1 && item bsd ${space} BSD Installs ||
#iseq ${menu_freedos} 1 && item freedos ${space} FreeDOS ||
iseq ${menu_live} 1 && item live ${space} Live Boot ||
iseq ${menu_security} 1 && item security ${space} Security Related ||
item --gap Tools:
iseq ${menu_utils} 1 && item utils ${space} Utilities ||
iseq ${arch} x86_64 && set bits 64 || set bits 32
item changebits ${space} Architecture: ${arch} (${bits}bit)
item shell ${space} iPXE shell
item netinfo ${space} Network card info
item
item --gap Har du problemer?
item --gap Ta kontakt med Tech:Support
item --gap i servicedesk.
isset ${menu} && set timeout 0 || set timeout 5000
choose --timeout ${timeout} --default ${menu} menu || goto local
echo ${cls}
goto ${menu} ||
iseq ${sigs_enabled} true && goto verify_sigs || goto change_menu
:verify_sigs
imgverify ${menu}.ipxe ${sigs}${menu}.ipxe.sig || goto error
goto change_menu
:change_menu
chain ${menu}.ipxe || goto error
goto main_menu
:error
echo
echo Error occured
echo Press any key to return to menu ...
prompt
goto main_menu
:local
echo Booting from local disks ...
exit 0
:shell
echo Type "exit" to return to menu.
set menu main_menu
shell
goto main_menu
:changebits
iseq ${arch} x86_64 && set arch i386 || set arch x86_64
goto main_menu
:sig_check
iseq ${sigs_enabled} true && set sigs_enabled false || set sigs_enabled true
goto main_menu
:img_sigs_check
iseq ${img_sigs_enabled} true && set img_sigs_enabled false || set img_sigs_enabled true
goto main_menu
|
